rxn_wennberg_tunneling.F90

Go to the documentation of this file.

! Copyright (C) 2021 Barcelona Supercomputing Center,
!  University of Illinois at Urbana-Champaign, and
!  National Center for Atmospheric Research
! SPDX-License-Identifier: MIT
 
!> \file
!> The camp_rxn_wennberg_tunneling module.
 
!> \page camp_rxn_wennberg_tunneling CAMP: Wennberg Tunneling Reaction
!!
!! Wennberg tunneling reaction rate constant equations are calculated as follows:
!!
!! \f[
!!   Ae^{(\frac{-B}{T})}e^{(\frac{C}{T^3})}
!! \f]
!!
!! where \f$A\f$ is the pre-exponential factor
!! (\f$(\mbox{#}\,\mbox{cm}^{-3})^{-(n-1)}\mbox{s}^{-1}\f$),
!! and \f$B\f$ and \f$C\f$ are parameters that capture the temperature
!! dependence as described in Wennberg et al. (2018) \cite Wennberg2018 .
!!
!! Input data for Wennberg tunneling equations has the following format:
!! \code{.json}
!!   {
!!     "type" : "WENNBERG_TUNNELING",
!!     "A" : 123.45,
!!     "B"  : 1200.0,
!!     "C"  : 1.0e8,
!!     "time unit" : "MIN",
!!     "reactants" : {
!!       "spec1" : {},
!!       "spec2" : { "qty" : 2 },
!!       ...
!!     },
!!     "products" : {
!!       "spec3" : {},
!!       "spec4" : { "yield" : 0.65 },
!!       ...
!!     }
!!   }
!! \endcode
!! The key-value pairs \b reactants, and \b products are required. Reactants
!! without a \b qty value are assumed to appear once in the reaction equation.
!! Products without a specified \b yield are assumed to have a \b yield of
!! 1.0.
!!
!! When \b A is not included, it is assumed to be 1.0, when \b B is not
!! included, it is assumed to be 0.0 K, and when \b C is not included, it is
!! assumed to be 0.0 \f$\mbox{K}^3\f$.
!! The unit for time is assumed to be s, but inclusion of the optional
!! key-value pair \b time \b unit = \b MIN can be used to indicate a rate
!! with min as the time unit.
 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
!> The rxn_wennberg_tunneling_t type and associated functions.
module camp_rxn_wennberg_tunneling
 
  use camp_aero_rep_data
  use camp_chem_spec_data
  use camp_constants,                        only: const
  use camp_camp_state
  use camp_property
  use camp_rxn_data
  use camp_util,                             only: i_kind, dp, to_string, &
                                                  assert, assert_msg, die_msg
 
  implicit none
  private
 
#define NUM_REACT_ this%condensed_data_int(1)
#define NUM_PROD_ this%condensed_data_int(2)
#define A_ this%condensed_data_real(1)
#define B_ this%condensed_data_real(2)
#define C_ this%condensed_data_real(3)
#define CONV_ this%condensed_data_real(4)
#define NUM_INT_PROP_ 2
#define NUM_REAL_PROP_ 4
#define NUM_ENV_PARAM_ 1
#define REACT_(x) this%condensed_data_int(NUM_INT_PROP_ + x)
#define PROD_(x) this%condensed_data_int(NUM_INT_PROP_ + NUM_REACT_ + x)
#define DERIV_ID_(x) this%condensed_data_int(NUM_INT_PROP_ + NUM_REACT_ + NUM_PROD_ + x)
#define JAC_ID_(x) this%condensed_data_int(NUM_INT_PROP_ + 2*(NUM_REACT_+NUM_PROD_) + x)
#define YIELD_(x) this%condensed_data_real(NUM_REAL_PROP_ + x)
 
  public :: rxn_wennberg_tunneling_t
 
  !> Generic test reaction data type
  type, extends(rxn_data_t) :: rxn_wennberg_tunneling_t
  contains
    !> Reaction initialization
    procedure :: initialize
    !> Finalize the reaction
    final :: finalize, finalize_array
  end type rxn_wennberg_tunneling_t
 
  !> Constructor for rxn_wennberg_tunneling_t
  interface rxn_wennberg_tunneling_t
    procedure :: constructor
  end interface rxn_wennberg_tunneling_t
 
contains
 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
  !> Constructor for Wennberg tunneling reaction
  function constructor() result(new_obj)
 
    !> A new reaction instance
    type(rxn_wennberg_tunneling_t), pointer :: new_obj
 
    allocate(new_obj)
    new_obj%rxn_phase = gas_rxn
 
  end function constructor
 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
  !> Initialize the reaction data, validating component data and loading
  !! any required information into the condensed data arrays for use during
  !! solving
  subroutine initialize(this, chem_spec_data, aero_rep, n_cells)
 
    !> Reaction data
    class(rxn_wennberg_tunneling_t), intent(inout) :: this
    !> Chemical species data
    type(chem_spec_data_t), intent(in) :: chem_spec_data
    !> Aerosol representations
    type(aero_rep_data_ptr), pointer, intent(in) :: aero_rep(:)
    !> Number of grid cells being solved simultaneously
    integer(kind=i_kind), intent(in) :: n_cells
 
    type(property_t), pointer :: spec_props, reactants, products
    character(len=:), allocatable :: key_name, spec_name, string_val
    integer(kind=i_kind) :: i_spec, i_qty
 
    integer(kind=i_kind) :: temp_int
    real(kind=dp) :: temp_real
 
    ! Get the species involved
    if (.not. associated(this%property_set)) call die_msg(255324828, &
            "Missing property set needed to initialize reaction")
    key_name = "reactants"
    call assert_msg(362119416, &
            this%property_set%get_property_t(key_name, reactants), &
            "Wennberg tunneling reaction is missing reactants")
    key_name = "products"
    call assert_msg(409429361, &
            this%property_set%get_property_t(key_name, products), &
            "Wennberg tunneling reaction is missing products")
 
    ! Count the number of reactants (including those with a qty specified)
    call reactants%iter_reset()
    i_spec = 0
    do while (reactants%get_key(spec_name))
      ! Get properties included with this reactant in the reaction data
      call assert(463909147, reactants%get_property_t(val=spec_props))
      key_name = "qty"
      if (spec_props%get_int(key_name, temp_int)) i_spec = i_spec+temp_int-1
      call reactants%iter_next()
      i_spec = i_spec + 1
    end do
 
    ! Allocate space in the condensed data arrays
    allocate(this%condensed_data_int(num_int_prop_ + &
            (i_spec + 2) * (i_spec + products%size())))
    allocate(this%condensed_data_real(num_real_prop_ + products%size()))
    this%condensed_data_int(:) = int(0, kind=i_kind)
    this%condensed_data_real(:) = real(0.0, kind=dp)
 
    ! Save space for the environment dependent parameters
    this%num_env_params = num_env_param_
 
    ! Save the size of the reactant and product arrays (for reactions where
    ! these can vary)
    num_react_ = i_spec
    num_prod_ = products%size()
 
    ! Set the #/cc -> ppm conversion prefactor
    conv_ = const%avagadro / const%univ_gas_const * 10.0d0**(-12.0d0)
 
    ! Get reaction parameters (it might be easiest to keep these at the
    ! beginning of the condensed data array, so they can be accessed using
    ! compliler flags)
    key_name = "A"
    if (.not. this%property_set%get_real(key_name, a_)) then
      a_ = 1.0
    end if
    key_name = "time unit"
    if (this%property_set%get_string(key_name, string_val)) then
      if (trim(string_val).eq."MIN") then
        a_ = a_ / 60.0
      end if
    endif
    key_name = "B"
    if (.not. this%property_set%get_real(key_name, b_)) then
      b_ = 0.0
    end if
    key_name = "C"
    if (.not. this%property_set%get_real(key_name, c_)) then
      c_ = 0.0
    end if
 
    ! Get the indices and chemical properties for the reactants
    call reactants%iter_reset()
    i_spec = 1
    do while (reactants%get_key(spec_name))
 
      ! Save the index of this species in the state variable array
      react_(i_spec) = chem_spec_data%gas_state_id(spec_name)
 
      ! Make sure the species exists
      call assert_msg(292299004, react_(i_spec).gt.0, &
              "Missing Wennberg tunneling reactant: "//spec_name)
 
      ! Get properties included with this reactant in the reaction data
      call assert(687092598, reactants%get_property_t(val=spec_props))
      key_name = "qty"
      if (spec_props%get_int(key_name, temp_int)) then
        do i_qty = 1, temp_int - 1
          react_(i_spec + i_qty) = react_(i_spec)
        end do
        i_spec = i_spec + temp_int - 1
      end if
 
      call reactants%iter_next()
      i_spec = i_spec + 1
    end do
 
    ! Get the indices and chemical properties for the products
    call products%iter_reset()
    i_spec = 1
    do while (products%get_key(spec_name))
 
      ! Save the index of this species in the state variable array
      prod_(i_spec) = chem_spec_data%gas_state_id(spec_name)
 
      ! Make sure the species exists
      call assert_msg(681828291, prod_(i_spec).gt.0, &
              "Missing Wennberg tunneling product: "//spec_name)
 
      ! Get properties included with this product in the reaction data
      call assert(794146636, products%get_property_t(val=spec_props))
      key_name = "yield"
      if (spec_props%get_real(key_name, temp_real)) then
        yield_(i_spec) = temp_real
      else
        yield_(i_spec) = 1.0
      end if
 
      call products%iter_next()
      i_spec = i_spec + 1
    end do
 
  end subroutine initialize
 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
  !> Finalize the reaction
  subroutine finalize(this)
 
    !> Reaction data
    type(rxn_wennberg_tunneling_t), intent(inout) :: this
 
    if (associated(this%property_set)) &
            deallocate(this%property_set)
    if (allocated(this%condensed_data_real)) &
            deallocate(this%condensed_data_real)
    if (allocated(this%condensed_data_int)) &
            deallocate(this%condensed_data_int)
 
  end subroutine finalize
 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
  !> Finalize an array of reactions
  subroutine finalize_array(this)
  
    !> Array of reaction data
    type(rxn_wennberg_tunneling_t), intent(inout) :: this(:)
 
    integer(kind=i_kind) :: i_rxn
 
    do i_rxn = 1, size(this)
      call finalize(this(i_rxn))
    end do
 
  end subroutine finalize_array
 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
end module camp_rxn_wennberg_tunneling