camp_box_model.F90

Go to the documentation of this file.

! Copyright (C) 2021 Barcelona Supercomputing Center and University of
! Illinois at Urbana-Champaign
! SPDX-License-Identifier: MIT
 
!> \file
!> The camp_camp_box_model program
 
!> Driver for the \ref index "CAMP" box model
program camp_camp_box_model
 
  use camp_camp_box_model_data
  use camp_util
 
  implicit none
 
  ! New-line character
  character(len=*), parameter :: new_line = char(10)
  ! Output file unit
  integer(kind=i_kind), parameter :: output_file_unit = 7
 
  ! Config file list path
  character(len=300) :: config_file_arg
  character(len=:), allocatable :: config_file
  ! Output file name
  character(len=300) :: output_file_arg
  character(len=:), allocatable :: output_file_prefix, output_file
 
  ! The box model data
  type(camp_box_model_data_t), pointer :: box_model
 
  ! Get the configuration and output file names
  if ( command_argument_count( ) /= 2 ) then
    write(*,*) "Usage: camp_box_model box_model_config.json "// &
               "output_file_prefix"
    write(*,*) "Output files created"
    write(*,*) "   output_file_prefix_results.txt: Box model results"
    write(*,*) "   output_file_prefix.conf: GNU Plot configuration file "// &
               "for plotting results"
    call die_msg( 695622653, "Incorrect number of command line arguments" )
  end if
  call get_command_argument( 1, config_file_arg )
  call get_command_argument( 2, output_file_arg )
  config_file        = trim( config_file_arg )
  output_file_prefix = trim( output_file_arg )
 
  ! Create a new box model
  box_model => camp_box_model_data_t( config_file )
 
  call box_model%print( )
 
  ! Open the output file
  output_file = output_file_prefix//"_results.txt"
  open( unit = output_file_unit, file = output_file, status = "replace", &
        action = "write" )
 
  ! Run the camp-chem box model
  call box_model%run( output_file_unit )
 
  ! Close the output file
  close( output_file_unit )
 
  ! Create the GNU Plot config file
  call box_model%create_gnuplot_config_file( output_file_prefix )
 
  ! Free the box model and local variables
  deallocate( box_model )
  deallocate( config_file )
  deallocate( output_file_prefix )
  deallocate( output_file )
 
end program camp_camp_box_model